Cannot find a few things in the documentation

[thomasd3]

• Displaying a range of dates:

  Chart.withXAxis (LayoutObjects.LinearAxis.init(Range = ?)

How can I set from DateTime A to DateTime B?

The StyleParam.Range type seems to want floats, but the comments in the code say:

If the axis typeis "date", it should be date strings, like date data, though Date objects and unix milliseconds will be accepted and converted to strings.

• Sizing subplots:

    [
        chart1
        chart2  |> Chart.withSize(Height = 200)    <- this will get ignored
    ]
    |> Chart.SingleStack(Pattern= LayoutGridPattern.Coupled)
    |> Chart.withSize(Width = 1600, Height= 800)
    |> Chart.show
  

I can't find where I can set a size for each plot

[kMutagene]

The StyleParam.Range type seems to want floats

What version are you on? i fixed that recently and it should now take IConvertible (meaning strings and System.DateTime work both)

Good find with the comments though, i'll fix that. These are usually straight copies of plotly.js docs and sometimes dont fit perfectly. In our case it is enough to use System.DateTime (without any conversion to timestamps or date strings):

#r "nuget: Plotly.NET, 2.0.0-preview.18"

open Plotly.NET

Chart.Line [
    System.DateTime.Parse("01/02/2022"), 1
    System.DateTime.Parse("01/03/2022"), 2
    System.DateTime.Parse("01/04/2022"), 3
    System.DateTime.Parse("01/05/2022"), 4
]
|> Chart.withXAxisStyle(
    MinMax = (System.DateTime.Parse("01/01/2022"),System.DateTime.Parse("01/06/2022"))
)

(alternative using withXAxis) :

|> Chart.withXAxis(
    LayoutObjects.LinearAxis.init(
        Range = StyleParam.Range.MinMax(System.DateTime.Parse("01/01/2022"),System.DateTime.Parse("01/06/2022")
        )
    )
)

Regarding your questions with subplots:

There is currently no easy way of changing grid sizes with the high level Chart.Grid / Chart.SingleStack APIs. Until that is added, you can still create such subplots yourself by setting the domains of the subplot axes:

[
    Chart.Line [1,2 ; 3,4]
    |> Chart.withAxisAnchor(X=1, Y=1)
    Chart.Line [1,2 ; 3,4]
    |> Chart.withAxisAnchor(X=1, Y=2)
]
|> Chart.combine
|> Chart.withYAxis(
    LayoutObjects.LinearAxis.init(Domain = StyleParam.Range.MinMax(0.,0.65)),
    Id = StyleParam.SubPlotId.YAxis 1
)
|> Chart.withYAxis(
    LayoutObjects.LinearAxis.init(Domain = StyleParam.Range.MinMax(0.7,1.)),
    Id = StyleParam.SubPlotId.YAxis 2
)

[thomasd3]

Hi,
I'm using 2.0.0.preview.16 (just upgraded to preview 18)
The range solution worked well.

When it comes to the layout, this fails when I deal with shapes:

    [
        (candleChart @ pricesChart @ tradesChart)
        |> Chart.combine
        |> Chart.withShapes (zonesChartAnalysis @ liquidityLinesChart @ fairPriceLinesChart )
        |> Chart.withAxisAnchor(X=1, Y=1)
        
        ATRChart
        |> Chart.withAxisAnchor(X=1, Y=2)
    ]
    |> Chart.combine
    |> Chart.withConfig config
    |> Chart.withXAxis (
            LayoutObjects.LinearAxis.init(
                RangeSlider = LayoutObjects.RangeSlider.init(Visible = false),
                Range = StyleParam.Range.MinMax(firstTrade.Timestamp, lastCandle.Timestamp)
            )
        ) //, ShowGrid = false))
    |> Chart.withYAxis (
            LayoutObjects.LinearAxis.init(
                    AutoRange = StyleParam.AutoRange.True,
                    FixedRange = false,
                    Domain = StyleParam.Range.MinMax(0., 0.85)
                ),
            Id = StyleParam.SubPlotId.YAxis 1                
        )
    |> Chart.withYAxis (
            LayoutObjects.LinearAxis.init(
                    AutoRange = StyleParam.AutoRange.True,
                    FixedRange = false,
                    Domain = StyleParam.Range.MinMax(0.90, 1.)
                ),
            Id = StyleParam.SubPlotId.YAxis 2                
        )

In the end, I get this:

Where the part:

        (candleChart @ pricesChart @ tradesChart)
        |> Chart.combine
        |> Chart.withShapes (zonesChartAnalysis @ liquidityLinesChart @ fairPriceLinesChart )

gets split: the top part goes to the right subplot, while the shapes go to the second subplot.

[kMutagene]

While i would appreciate a reproducible minimal example, i am pretty sure you should be good by setting the Yref of the shapes, which works the same for shapes as axis anchors for traces.

Dope looking plot though!

#r "nuget: Plotly.NET, 2.0.0-preview.18"

open Plotly.NET
open Plotly.NET.LayoutObjects
[
    Chart.Line [1,2 ; 3,4]
    |> Chart.withAxisAnchor(X=1, Y=1)
    Chart.Line [1,2 ; 3,4]
    |> Chart.withAxisAnchor(X=1, Y=2)
]
|> Chart.combine
|> Chart.withYAxis(
    LayoutObjects.LinearAxis.init(Domain = StyleParam.Range.MinMax(0.,0.65)),
    Id = StyleParam.SubPlotId.YAxis 1
)
|> Chart.withYAxis(
    LayoutObjects.LinearAxis.init(Domain = StyleParam.Range.MinMax(0.7,1.)),
    Id = StyleParam.SubPlotId.YAxis 2
)
|> Chart.withShapes [
    Shape.init(X0 = 1, X1 = 2, Y0 = 1, Y1 = 2, Yref = "y1")
    Shape.init(X0 = 1, X1 = 2, Y0 = 1, Y1 = 2, Yref = "y2")
]